MapInfo Pro

Here's how I would approach it.

1. You have your footpath polyline and you know at what end you need to create a new line to extend to the neighboring polyline.
2. Now fetch the two last points from that end of the polyline; P1 and P2 in the drawing below.
3. Create a line from these two points, P2 to P1
4. Calculate the direction of that line using OBJDirection() from the OBJLib module.
5. Now you need to offset a point, P3, in the direction of the line so that it ends "on the other side" of the street polyline. You can offset it by 10 meters or a known tolerance, and if that's not enough offset it again. You can use intersect to determine if the line intersects the streetpolyline. You can use the MapBasic function CartesianOffset(), and create a line from P1 and P3. Also, remember to use the direction calculated in 3.
6. Now calculate the intersection between Footpath line and Street Polyline, P4. Use the MapBasic function IntersectNodes() to get the intersection point. You get this as a polyline so you have to extract the node from the polyline.
7. Finally, you can create the new Footpath line using P1 and P4

Function OBJCreateLineExtension(	  ByVal oFromPline As Object			'One-segment polyline
							, ByVal nFromStartOrEnd As Integer		'OBJ_FIRST_SEGMENT (1), OBJ_LAST_SEGMENT (-1)
							, ByVal fLength As Float				'Length of Line Extension
							, ByVal sDistanceUnits As String		'Distance units
							, ByVal nCalculationMethod As Integer	'CALC_METHOD_CARTESIAN / CALC_METHOD_SPHERICAL
							) As Object						'Returns a point at (0,0) if the process fails

Dim	oNewLine, oP2, oP3 As Object,
	nNumPnts As Integer,
	fX, fY, fAngle As Float

OnError GoTo ErrorOccured

OBJCreateLineExtension = CreatePoint(0,0)

	If nFromStartOrEnd = OBJ_FIRST_SEGMENT Then	'Start Segment
		oNewLine	= OBJReverse(ExtractNodes(oFromPline, 1, 1, 2, FALSE))
	Else	'Assuming OBJ_LAST_SEGMENT
		nNumPnts	= ObjectInfo(oFromPline, OBJ_INFO_NPOLYGONS + 1)
		oNewLine	= ExtractNodes(oFromPline, 1, nNumPnts - 1, nNumPnts, FALSE)
	End If

	fAngle	= OBJDirection(oNewLine)

	fX		= ObjectNodeX(oNewLine, 1, 2)
	fY		= ObjectNodeY(oNewLine, 1, 2)
	oP2		= CreatePoint(fX, fY)

	If nCalculationMethod  = CALC_METHOD_CARTESIAN Then
		oP3		= CartesianOffset(oP2, fAngle, fLength, sDistanceUnits)
	Else
		oP3		= SphericalOffset(oP2, fAngle, fLength, sDistanceUnits)
	End If

	oNewLine	= OBJCreatePlineFromPoints(oP2, oP3)

	OBJCreateLineExtension = oNewLine

	Exit Function
'-------------------------
ErrorOccured:
	Call ERRCreate(Err(), Error$(), "OBJCreateLineExtension")
	Call ERRShow()

End Function

Function OBJCreateLineToIntersection(	  ByVal oFromPline As Object			'2-node polyline
								, ByVal nFromStartOrEnd As Integer		'OBJ_FIRST_SEGMENT (1), OBJ_LAST_SEGMENT (-1)
								, ByVal oToPline As Object			'multi-point polyline
								, ByVal fDistanceTolerance As Float	'Search distance
								, ByVal sDistanceUnits As String		'Distance units
								, ByVal nCalculationMethod As Integer	'CALC_METHOD_CARTESIAN / CALC_METHOD_SPHERICAL
								) As Object						'Returns a point at (0,0) if no intersection was found

Dim	oNewLine, oIntersection As Object,
	nPnts, nNumPnts As Integer,
	fX, fY, fAngle As Float

OnError GoTo ErrorOccured

OBJCreateLineToIntersection = CreatePoint(0,0)

	oNewLine	= OBJCreateLineExtension(oFromPline, nFromStartOrEnd, fDistanceTolerance, sDistanceUnits, nCalculationMethod)

	If Not oNewLine Intersects oToPline Then
		Call ERRCreate(0, "Extended line doesn't intersect line to extend to", "OBJCreateLineToIntersection")
		Exit Function
	End If

	oIntersection	= IntersectNodes(oNewLine, oToPline, INCL_CROSSINGS)
	nNumPnts		= ObjectInfo(oIntersection, OBJ_INFO_NPNTS)

	If nNumPnts = 0 Then
		Call ERRCreate(0, "Extended line doesn't intersect line to extend to", "OBJCreateLineToIntersection")
		Exit Function
	End If

	fX	= ObjectNodeX(oNewLine, 1, 1)
	fY	= ObjectNodeY(oNewLine, 1, 1)
	Create Pline
		Into Variable oNewLine
		1 (fX, fY)

	For nPnts = 1 To nNumPnts
		Alter Object oNewLine
			Node Add Position 1, (nPnts + 1) (ObjectNodeX(oIntersection, 1, nPnts), ObjectNodeY(oIntersection, 1, nPnts))
	Next

	OBJCreateLineToIntersection = oNewLine

	Exit Function
'-------------------------
ErrorOccured:
	Call ERRCreate(Err(), Error$(), "OBJCreateLineToIntersection")
	Call ERRShow()

End Function

As you can see, this function uses the first custom function for creating the extension line. Then it calculates the intersection point and creates a new polyline from the first node of the extension line and the intersection point.

• OBJLib which is part of the Common MapBasic Library
• DrawTools, the source code for the tool can be found in the module DrawTools.mb

DrawTools hasn't yet been updated with this new feature in MapInfo Marketplace. It may take a couple of weeks as I'm adding additional capabilities to it before publishing a new version.

Let me know if you find such a tool useful and if it's enough to extend to the same layer that you add the new polyline to.